MacPeople 1998 #2/MACPEOPLE-1998-NO2.ISO/アップル関連/ARA PS アップデート/モデム用/OMRON ME2814B3 ARA2/OMRON ME2814B3 ARA2

Text File | 1996-04-20 | 14KB | 714 lines

!**************************************************************************
!    OMRON ME2814B3 ARA Ver2.0 JAPAN
!    1996/04/20 Ver1.0
!    Written by OMRON Corp.
!
!  'mlts' resource info for this modem:
!    byte 1 == 01 -> modem HAS builtin reliability protocols
!    byte 2 == 00 -> reserved by Apple
!    byte 3 == 23 -> max hex chars in varstr 7 (35 dec)
!    byte 4 == 23 -> max hex chars in varstr 8
!    byte 5 == 23 -> max hex chars in varstr 9
!
!**************************************************************************
@ORIGINATE
@ANSWER
!------------------------
! reset the serial port
!------------------------
HSReset 0 0 0 0 0 0
@LABEL 1
DTRClear
pause 10
DTRSet
pause 3
! Mac talks to the modem at 28,800 bps.
serreset 19200, 0, 8, 1
setspeed 38400
matchclr
settries 0
! Modem initialize ATZ
@LABEL 2
matchclr
matchstr 1 3 "OK¥13¥10"
matchstr 2 3 "0¥13"
write "ATZ¥13"
matchread 15
inctries
iftries 3 3
jump 2
! Modem Setting
! E0  - Command Echo Off
! Q0  - Command Response On
! V1  - Command Response Format Word
! M1  - Speaker Moniter on until carrier detected
! &C1 - Carrier Signal Detect Carrier from the remote modem
! &D2 - Data Terminal Ready Control On to Off on-hook
! &S1 - Activates DSR before handshaking
! &B1 - DTE Speed Setting 19200bps
! &A3 - Result Error Corection Type
! &M0 - Error Colection V.42-Off & MNP-Off
! &H1&R1&I0 - CTS Hardware flow Control
! S0=0 - Don't answer calls
@LABEL 3
matchclr
matchstr 1 4 "OK¥13¥10"
pause 2
write "ATE0Q0V1M1&C1&D2&S1X4&B1&A0&M0&H1&R1&I0S0=0¥13"
matchread 15
inctries
iftries 3 105
jump 3
!-----------------------------------------
! Modem responding & configured.
! determine if reliable link is requested.
!-----------------------------------------
@LABEL 4
! if modem mnp10 link requested (var 4 == 2) then jump label 5
ifstr 4 5 "2"
!
! if modem v42 link requested (var 4 == 1) then jump label 6
ifstr 4 6 "1"
!
! if no modem v42 link requested (var 4 == 0) [same as ARA 1.0] then jump label 9
ifstr 4 8 "0"
!
! else invalid value in var 4; exit w/error
jump 110
!--------------------------------
! MNP10 Link Setting.
!--------------------------------
@LABEL 5
matchclr
matchstr 1 7 "OK¥13¥10"
! S15=128 - V.42-Off
! &M4 - MNP-On
! &K0 - DATACOMP-Off
pause 2
write "AT&M4&K0&A3S15=128¥13"
matchread 15
inctries
iftries 3 105
jump 5
!-----------------------------------------------------
! V.42 Link Setting V.42 --> MNP --> Normal
!-----------------------------------------------------
@LABEL 6
matchclr
matchstr 1 7 "OK¥13¥10"
! &M4S - v42 autoreliable mode
pause 2
write "AT&M4&K0&A3S15=8¥13"
matchread 15
inctries
iftries 3 105
jump 6
!------------------------------------------------------------------------
! If we DID support compression in the modem, this is where it would go.
!------------------------------------------------------------------------
@LABEL 7
!
!
!
!------------------------------------------------------------------------
! Set ID OMRON MD2814B3.
!------------------------------------------------------------------------
@LABEL 8
matchclr
matchstr 1 9 "3362¥13¥10¥13¥10OK¥13¥10"
pause 2
write "ATI0¥13"
matchread 15
inctries
iftries 3 105
jump 8
!--------------------------------------------------------------------------
! If speaker on flag is true, jump to label 13.  Else turn off the speaker.
!--------------------------------------------------------------------------
@LABEL 9
ifstr 2 13 "1"
pause 5
matchclr
matchstr 1 13 "OK¥13¥10"
pause 2
write "ATM0¥13"
matchread 15
inctries
iftries 3 105
jump 9
!*******************************************************************************
! modem ready, so enable answering or originate a call - label range is 11-30
!
!
!*******************************************************************************
@LABEL 13
pause 5
ifANSWER 100
!
! if normal dialing (parm 6 == 0) jump to 19
ifstr 6 19 "0"
!
! if blind dialing (parm 6 == 1) jump to 17
ifstr 6 17 "1"
!
! if manual dialing (parm 6 == 2) jump to 15
ifstr 6 15 "2"
!
! else invalid value in var 6; exit w/error
jump 110
!
!
!
@LABEL 15
note "手動で発信をしています。" 3
! X1 to ignore dialtone & busy for manual dialing, D to dial
write "ATX1D ¥13"
jump 32
!
!
!
@LABEL 17
matchclr
matchstr 1 19 "OK¥13¥10"
! X3 to ignore dialtone for blind dialing
pause 2
write "ATX3¥13"
matchread 30
inctries
iftries 3 105
jump 17
!
!
!
@LABEL 19
! this is where we break up long dialstrings
!
! parm 1 is always the full dialstring from the conn doc
!note "Dialing ^1" 3
note "^1に電話をしています。" 3
! parm 3 is always "p" for pulse & "t" for tone
!
! if parm 8 == blank (complete dialstring in parm 7)
!  then jump to label 27 & dial parm 7
ifstr 8 27 " "
!
! if parm 9 == blank (complete dialstring in parms 7 & 8)
!  then jump to label 24 & dial parm 7 & 8
ifstr 9 24 " "
!
!  else dial parm 7 & 8 & 9 (complete dialstring in parms 7, 8 & 9)
matchclr
matchstr 1 21 "OK¥13¥10"
! parm 7 holds first string fragment
write "ATD^3^7;¥13"
matchread 500
! modem not responding; bailout.
jump 105
!
!
!
@LABEL 21
! parm 8 holds second string fragment
matchclr
matchstr 1 22 "OK¥13¥10"
write "ATD^3^8;¥13"
matchread 500
! modem not responding; bailout.
jump 105
!
!
!
@LABEL 22
! parm 9 holds last string fragment
write "ATD^3^9¥13"
jump 32
!
!
!
!
@LABEL 24
matchclr
matchstr 1 25 "OK¥13¥10"
! parm 7 holds first string fragment
write "ATD^3^7;¥13"
matchread 500
! modem not responding; bailout.
jump 105
!
!
!
@LABEL 25
! parm 8 holds last string fragment
write "ATD^3^8¥13"
jump 32
!
!
!
@LABEL 27
! parm 7 holds entire string
write "ATD^3^7¥13"
jump 32
!***********************************************
!    connecting - label range is 34-99
!
!
!***********************************************
@LABEL 32
matchclr
!
matchstr 1  34 "CONNECT 1200¥13¥10"
matchstr 2  34 "CONNECT 1200/NONE¥13¥10"
matchstr 3  35 "CONNECT 1200/ARQ"
!
matchstr 4  38 "CONNECT 2400¥13¥10"
matchstr 5  38 "CONNECT 2400/NONE¥13¥10"
matchstr 6  39 "CONNECT 2400/ARQ"
!
matchstr 7  42 "CONNECT 4800¥13¥10"
matchstr 8  42 "CONNECT 4800/V"
matchstr 9  43 "CONNECT 4800/ARQ"
!
matchstr 10 46 "CONNECT 7200¥13¥10"
matchstr 11 46 "CONNECT 7200/V"
matchstr 12 47 "CONNECT 7200/ARQ"
!
matchstr 13 50 "CONNECT 9600¥13¥10"
matchstr 14 50 "CONNECT 9600/V"
matchstr 15 51 "CONNECT 9600/ARQ"
!
matchstr 16 54 "CONNECT 12000¥13¥10"
matchstr 17 54 "CONNECT 12000/V"
matchstr 18 55 "CONNECT 12000/ARQ"
!
matchstr 19 58 "CONNECT 14400¥13¥10"
matchstr 20 58 "CONNECT 14400/V"
matchstr 21 59 "CONNECT 14400/ARQ"
!
matchstr 22 62 "CONNECT 16800¥13¥10"
matchstr 23 62 "CONNECT 16800/V"
matchstr 24 63 "CONNECT 16800/ARQ"
!
matchstr 25 66 "CONNECT 19200¥13¥10"
matchstr 26 66 "CONNECT 19200/V"
matchstr 27 67 "CONNECT 19200/ARQ"
!
matchstr 28 70 "CONNECT 21600¥13¥10"
matchstr 29 70 "CONNECT 21600/V"
matchstr 30 71 "CONNECT 21600/ARQ"
!
matchstr 31 74 "CONNECT 24000¥13¥10"
matchstr 32 74 "CONNECT 24000/V"
matchstr 33 75 "CONNECT 24000/ARQ"
!
matchstr 34 78 "CONNECT 26400¥13¥10"
matchstr 35 78 "CONNECT 26400/V"
matchstr 36 79 "CONNECT 26400/ARQ"
!
matchstr 37 82 "CONNECT 28800¥13¥10"
matchstr 38 82 "CONNECT 28800/V"
matchstr 39 83 "CONNECT 28800/ARQ"
!
! other result codes.
!
matchstr 40 101 "RING¥13¥10"
matchstr 41 106 "NO DIAL TONE¥13¥10"
matchstr 42 107 "NO CARRIER¥13¥10"
matchstr 43 107 "ERROR¥13¥10"
matchstr 44 108 "BUSY¥13¥10"
matchstr 45 111 "CONNECT¥13¥10"
!
matchread 700
jump 32
ifANSWER 32
jump 105
!------------------------------------------------------------
!  THIS v32b modem has been setup to do cts handshaking,
!  and we assume that a cts handshaking cable is being used,
!  so we leave the serial port set to 19,200 bps.
!------------------------------------------------------------
@LABEL 34
note "1200bpsで接続確認中" 3
CommunicatingAt 1200
jump 90
!
@LABEL 35
note "1200bps-MNPで接続確認中" 3
CommunicatingAt 1200
jump 90
!
@LABEL 36
note "1200bps-MNP10で接続確認中" 3
CommunicatingAt 1200
jump 90
!
@LABEL 37
note "1200bps-V.42で接続確認中" 3
CommunicatingAt 1200
jump 90
!
!
!
@LABEL 38
note "2400bpsで接続確認中" 3
CommunicatingAt 2400
jump 90
!
@LABEL 39
note "2400bps-MNPで接続確認中" 3
CommunicatingAt 2400
jump 90
!
@LABEL 40
note "2400bps-MNP10で接続確認中" 3
CommunicatingAt 2400
jump 90
!
@LABEL 41
note "2400bps-V.42で接続確認中" 3
CommunicatingAt 2400
jump 90
!
!
!
@LABEL 42
note "4800bpsで接続確認中" 3
CommunicatingAt 4800
jump 90
!
@LABEL 43
note "4800bps-MNPで接続確認中" 3
CommunicatingAt 4800
jump 90
!
@LABEL 44
note "4800bps-MNP10で接続確認中" 3
CommunicatingAt 4800
jump 90
!
@LABEL 45
note "4800bps-V.42で接続確認中" 3
CommunicatingAt 4800
jump 90
!
!
!
@LABEL 46
note "7200bpsで接続確認中" 3
CommunicatingAt 7200
jump 90
!
@LABEL 47
note "7200bps-MNPで接続確認中" 3
CommunicatingAt 7200
jump 90
!
@LABEL 48
note "7200bps-MNP10で接続確認中" 3
CommunicatingAt 7200
jump 90
!
@LABEL 49
note "7200bps-V.42で接続確認中" 3
CommunicatingAt 7200
jump 90
!
!
!
@LABEL 50
note "9600bpsで接続確認中" 3
CommunicatingAt 9600
jump 90
!
@LABEL 51
note "9600bps-MNPで接続確認中" 3
CommunicatingAt 9600
jump 90
!
@LABEL 52
note "9600bps-MNP10で接続確認中" 3
CommunicatingAt 9600
jump 90
!
@LABEL 53
note "9600bps-V.42で接続確認中" 3
CommunicatingAt 9600
jump 90
!
!
!
@LABEL 54
note "12000bpsで接続確認中" 3
CommunicatingAt 12000
jump 90
!
@LABEL 55
note "12000bps-MNPで接続確認中" 3
CommunicatingAt 12000
jump 90
!
@LABEL 56
note "12000bps-MNP10で接続確認中" 3
CommunicatingAt 12000
jump 90
!
@LABEL 57
note "12000bps-V.42で接続確認中" 3
CommunicatingAt 12000
jump 90
!
!
!
@LABEL 58
note "14400bpsで接続確認中" 3
CommunicatingAt 14400
jump 90
!
@LABEL 59
note "14400bps-MNPで接続確認中" 3
CommunicatingAt 14400
jump 90
!
@LABEL 60
note "14400bps-MNP10で接続確認中" 3
CommunicatingAt 14400
jump 90
!
@LABEL 61
note "14400bps-V.42で接続確認中" 3
CommunicatingAt 14400
jump 90
!
@LABEL 62
note "16800bpsで接続確認中" 3
CommunicatingAt 16800
jump 90
!
@LABEL 63
note "16800bps-MNPで接続確認中" 3
CommunicatingAt 16800
jump 90
!
@LABEL 65
note "16800bps-V.42で接続確認中" 3
CommunicatingAt 16800
jump 90
!
!
!
@LABEL 66
note "19200bpsで接続確認中" 3
CommunicatingAt 19200
jump 90
!
@LABEL 67
note "19200bps-MNPで接続確認中" 3
CommunicatingAt 19200
jump 90
!
@LABEL 69
note "19200bps-V.42で接続確認中" 3
CommunicatingAt 19200
jump 90
!
!
!
@LABEL 70
note "21600bpsで接続確認中" 3
CommunicatingAt 21600
jump 90
!
@LABEL 71
note "21600bps-MNPで接続確認中" 3
CommunicatingAt 21600
jump 90
!
@LABEL 73
note "21600bps-V.42で接続確認中" 3
CommunicatingAt 21600
jump 90
!
!
!
@LABEL 74
note "24000bpsで接続確認中" 3
CommunicatingAt 24000
jump 90
!
@LABEL 75
note "24000bps-MNPで接続確認中" 3
CommunicatingAt 24000
jump 90
!
@LABEL 77
note "24000bps-V.42で接続確認中" 3
CommunicatingAt 24000
jump 90
!
!
!
@LABEL 78
note "26400bpsで接続確認中" 3
CommunicatingAt 26400
jump 90
!
@LABEL 79
note "26400bps-MNPで接続確認中" 3
CommunicatingAt 26400
jump 90
!
@LABEL 81
note "26400bps-V.42で接続確認中" 3
CommunicatingAt 26400
jump 90
!
!
!
@LABEL 82
note "28800bpsで接続確認中" 3
CommunicatingAt 28800
jump 90
!
@LABEL 83
note "28800bps-MNPで接続確認中" 3
CommunicatingAt 28800
jump 90
!
@LABEL 85
note "28800bps-V.42で接続確認中" 3
CommunicatingAt 28800
jump 90
!
!
!
@LABEL 90
! turn on cts handshaking.
HSReset 0 1 0 0 0 0
!
pause 30
ifANSWER 91
pause 15
@LABEL 91
exit 0
!************************************************************
! @ANSWER
! Set the modem to answer on 1st ring - label range is 100-104
!
!************************************************************
@LABEL 100
matchclr
matchstr 1 32 "OK¥13¥10"
pause 2
write "ATS0=2¥13"
matchread 30
inctries
iftries 3 105
jump 100
!
@LABEL 101
ifORIGINATE 32
! claim the serial port
userhook 1
note "電話がかかってきました。" 2
jump 32
!************************************************
! error messages - label range is 105-114
!
!
!************************************************
! Modem Not Responding
@LABEL 105
exit -6019
!
! No Dial Tone
@LABEL 106
note "電話回線が接続されていない。または、０発信をしている場合はﾀﾞｲﾔﾙﾄｰﾝ検出無視にして下さい" 3
exit -6020
!
! No Carrier or Error
@LABEL 107
exit -6021
!
! Busy
@LABEL 108
exit -6022
!
! No Answer
@LABEL 109
exit -6023
!
! varstring invalid value
@LABEL 110
exit -6027
!
! Connect 300bps
@LABEL 111
exit -6002 "ARA doesn't support 300bps connection."
!
!********************************************
! Hang up the modem - label range is 115-120
!
!
!********************************************
@HANGUP
@LABEL 115
settries 0
HSReset 0 0 0 0 0 0
@LABEL 116
!----------------------------
! firstly try escape sequence
!----------------------------
serreset 19200, 0, 8, 1
setspeed 38400
matchclr
matchstr 1 117 "OK¥13¥10"
pause 10
write "+++"
matchread 15
!
@LABEL 117
!-------------------
! secondly try ATH
!-------------------
matchclr
matchstr 1 119 "NO CARRIER¥13¥10"
matchstr 2 119 "OK¥13¥10"
matchstr 3 119 "ERROR¥13¥10"
write "ATH¥13"
matchread 50
inctries
iftries 3 118
jump 117
!---------------------------------------
! finaly try On-to-Off DTR transitions
!---------------------------------------
@LABEL 118
DTRSet
pause 5
DTRClear
pause 5
DTRSet
flush
jump 119
!------------------------------
! recall the factory settings.
!------------------------------
@LABEL 119
serreset 19200, 0, 8, 1
setspeed 38400
pause 15
matchclr
matchstr 1 120 "OK¥13¥10"
write "ATS0=0¥13"
matchread 30
inctries
iftries 3 105
jump 119
!
@LABEL 120
exit 0

!*********************************************************
! labels 121-128 are reserved for future emergency hacks
!
!
!*********************************************************